Sollya User's Manual

Name:

getbacktrace returns the list of Sollya procedures currently run

Library name:

sollya_obj_t sollya_lib_getbacktrace();

Usage:

getbacktrace() : void -> list

Description:

The getbacktrace command allows the stack of Sollya procedures that are currently run to be inspected. When called, getbacktrace returns an ordered list of structures, each of which contains an element passed_args and an element called_proc. The element called_proc contains the Sollya object representing the procedure being run. The element passed_args contains an ordered list of all effective arguments passed to the procedure when it was called. The procedure called last (i.e., on top of the stack) comes first in the list returned by getbacktrace. When any of the procedure called takes no arguments, the passed_arg element of the corresponding structure evaluates to an empty list.
When called from outside any procedure (at toplevel), getbacktrace returns an empty list.
When called for a stack containing a call to a variadic procedure that was called with an infinite number of effective arguments, the corresponding passed_args element evaluates to an end-elliptic list.

Example 1:

   > procedure testA() {
       "Current backtrace:";
       getbacktrace();
     };
   > procedure testB(X) {
       "X = ", X;
       testA();
     };
   > procedure testC(X, Y) {
       "X = ", X, ", Y = ", Y;
       testB(Y);
     };
   > testC(17, 42);
   X = 17, Y = 42
   X = 42
   Current backtrace:
   [|{ .passed_args = [| |], .called_proc = proc()
   {
   "Current backtrace:";
   getbacktrace();
   return void;
   } }, { .passed_args = [|42|], .called_proc = proc(X)
   {
   "X = ", X;
   testA();
   return void;
   } }, { .passed_args = [|17, 42|], .called_proc = proc(X, Y)
   {
   "X = ", X, ", Y = ", Y;
   testB(Y);
   return void;
   } }|]

Example 2:

> getbacktrace();
[| |]

Example 3:

   > procedure printnumargs(X) {
       var L, t;
       "number of arguments: ", X;
       L = getbacktrace();
       "Backtrace:";
       for t in L do {
         "  " @ objectname(t.called_proc) @ ", ", t.passed_args;
       };
     };
   > procedure numargs(l = ...) {
       "l[17] = ", l[17];
       printnumargs(length(l));
     };
   > procedure test() {
       numargs @ [|25, 26, 27 ...|];
     };
   > test();
   l[17] = 42
   number of arguments: infty
   Backtrace:
     printnumargs, [|infty|]
     numargs, [|25, 26, 27...|]
     test, [| |]

See also: proc, procedure, objectname, bind, @

Go back to the list of commands